３０年前に作ったゲーム

中１のときに作ったゲーム「ホンノウジ」を再現したプログラムです。
プログラムを実行してＥｎｔｅｒキーを押すとゲームスタートです。
「アケチ」と表示されたら素早くＥｎｔｅｒキーを押してください。
素早く押すことができれば天下統一です。

このプログラムは教育用プログラミング言語「ドリトル」で書きました。

// 早押しゲーム「ホンノウジ」

// プログラミング言語「ドリトル」

// インストール版ドリトルで実行してください。

// 2020.06.13  蕪木 孝

// 遊び方
// 1.本プログラムを実行する
// 2.Ｅｎｔｅｒキーを押してゲームスタート
// 3.「アケチ」と表示されたら素早くＥｎｔｅｒキーを押す


// -------------------- パラメータの設定 --------------------

表示間隔 = 0.5。	// 短くすると難易度が上がる (秒)

文字のサイズ = 30。	// 変更すると全体のサイズも変わる


// -------------------- 配列オブジェクトを作る --------------------

信長 = 配列 !
	"   **   "
	" __||__ "
	"|      |"
	"| -  - |"
	"|   |  |"
	"|  --  |"
	"|______|"
	"  |  /  "
	"   |/   "
	"   /    "
	"  /     "
作る。

// 表示ワード（１番目が正解ワード）
表示ワード  = 配列 ! "ｱｹﾁ" "ｱｷﾁ" "ｱｹｹ" "ﾏｹﾁ" "ｱｱｱ" 作る。


// -------------------- 初期処理 --------------------

// 文字関連
文字幅 = round(文字のサイズ / 2)。
文字高 = 文字のサイズ + 4。

// 表示領域関連
幅 = 文字幅 * 8。
高さ = 文字高 * 13。	// ワード 2行 + 信長 11行 = 13行
左上隅ｘ = round(幅 / 2) * (-1)。
左上隅ｙ = round(高さ / 2)。

画面 ! (黒) 塗る。

昔のモニターの表示色 = 色 ! 43 242 126 作る。
ラベル ! (昔のモニターの表示色) 文字の色。
ラベル ! (文字のサイズ) 文字サイズ。


// -------------------- ボタンオブジェクトを作る --------------------

ボタン１ = ボタン ! "" "ENTER" 作る。	// Ｅｎｔｅｒキーで押す
ボタン１ ! 消える。			// 表示はしない
ボタン１ : 状態 = 0。			// 0 はゲーム開始前
ボタン１ : 動作 = 
「
	「自分 : 状態 == 0」 ! なら 「
		自分 : 状態 = 1。	// ゲーム開始
	」
	そうでなければ 「
		自分 : 状態 = 2。	// Ｅｎｔｅｒキーを押した
	」 実行。
」。


// -------------------- 信長を表示する --------------------
「
	| i ; ｙ座標 |

	ｙ座標 = :左上隅ｙ - (:文字高 * 2) - ((i - 1) * :文字高) 。
	ラベル ! (:信長 ! (i) 読む) 作る (:左上隅ｘ) (ｙ座標) 位置。

」 ! (信長 ! 要素数？) 繰り返す。


// -------------------- ブロックを作る（ブロックは機能のかたまり）--------------------

// ワード表示位置のｘ座標の計算
// 　引数   : 表示ワードの文字列
// 　戻り値 : ｘ座標

ｘ座標の計算 = 「
	| str |
	round(:文字幅 * (str ! 長さ？) / 2) * (-1)。
」。


// -------------------- メイン --------------------

ラベル１ = ラベル ! 作る。	// ワード表示用のラベルオブジェクト
ラベル２ = ラベル ! 作る。	// 結果表示用のラベルオブジェクト

開始 = "Enterｷｰﾃﾞｽﾀｰﾄ"。
ｘ座標 = ｘ座標の計算 ! (開始) 実行する。
ラベル１ ! (ｘ座標) (左上隅ｙ) 位置    (開始) 書く。

表示ワードの数 = 表示ワード ! 要素数？。
番号 = 0。

タイマー１ = タイマー ! 作る   (表示間隔) 間隔    100 回数。

タイマー１ ! 「
	| i ; ｘ座標 |

	「ボタン１ : 状態 == 2」 ! なら 「	// Ｅｎｔｅｒキーを押したなら
		タイマー１ ! 中断。
	」
	そうでなければ　「ぜんぶ ! (ボタン１ : 状態 == 0) ( i <= 20) 本当」 なら 「
		// プログラム実行から (表示間隔 * 20) 秒間はＥｎｔｅｒキーが押されるのを待つ
		// その後は自動スタート
	」
	そうでなければ 「
		:番号 = random( :表示ワードの数 )。	// 表示ワードをランダムで選択
		ｘ座標 = ｘ座標の計算 ! (:表示ワード ! (:番号) 読む) 実行する。
		ラベル１ ! "" 書く。
		ラベル１ ! (ｘ座標) (:左上隅ｙ) 位置。
		ラベル１ ! (:表示ワード ! (:番号) 読む) 書く。 
	」 実行。

	「:番号 == 1」 ! なら 「タイマー１ ! 中断」 実行。	// 正解ワードが表示されたなら
」 実行。


タイマー１ ! 「
	 | ; 結果 ｘ座標 |

	「ぜんぶ ! (:番号 == 1) (ボタン１ : 状態 == 2) 本当」 ! なら 「
		結果 = "ﾃﾝｶﾄｳｲﾂ"。
	」
	そうでなければ 「
		結果 = "ｼｯﾊﾟｲ"。
	」 実行。

	ｘ座標 = ｘ座標の計算 ! (結果) 実行する。

	ラベル２ ! (ｘ座標) (:左上隅ｙ - :文字高) 位置    (結果) 書く。
」 最後に実行。

実行方法

インストール版ドリトルを以下のサイトからダウンロードしてください。
https://dolittle.eplang.jp/download
パソコンのＯＳがWindowsなら「Windows用」をクリックするとダウンロードがはじまります。
ダウンロードしたら解凍してください。
解凍したら dolittle.bat をダブルクリックするとドリトルが起動します。
プログラムを貼り付けて「実行！」をクリックするとゲーム画面が表示されます。

このゲームは当時ＢＡＳＩＣというプログラミング言語で作りました。
使ったパソコンは近所のバザーで１０００円で買ったＰＣ－８００１というモニターの表示が緑１色の機種でした。

弟しかプレイしたことがないホンノウジを誰でもプレイできる時代が来るとは。。。
中１の頃の自分も満足してくれると思います。