ProcessingでGenerative art#34

Processing.orgにあるExampleのFollowを参考に作りました。

Code

int num = 100;
float[] x = new float[num];
float[] y = new float[num];
float segLength = 5;
float hue;

void setup() {
  size(900, 600);
  pixelDensity(2);
  blendMode(ADD);
  colorMode(HSB, 360, 100, 100, 100);
  background(0);
  noFill();

  hue = random(360);
}

void draw() {
  stroke(hue, 80, 80, 50);
  dragSegment(0, mouseX, mouseY);
  for (int i=0; i<x.length-1; i++) {
    dragSegment(i+1, x[i], y[i]);
  }
}

void dragSegment(int i, float xin, float yin) {
  float dx = xin - x[i];
  float dy = yin - y[i];
  float angle = atan2(dy, dx);  
  x[i] = xin - cos(angle) * segLength;
  y[i] = yin - sin(angle) * segLength;
  segment(x[i], y[i], angle);
}

void segment(float x, float y, float a) {
  pushMatrix();
  translate(x, y);
  rotate(a);
  line(0, 0, segLength, 0);
  popMatrix();
}

void mouseReleased() {
  hue = random(360);
}

void keyPressed() {
  if (key == ENTER) {
    background(0);
  }
  if (key == ' ') {
    saveFrame("####.png");
  }
}