Toggl Track の記録を FileMaker に取り込む

2023年3月3日 04:51

僕はタイムトラッキングに Toggl Track を利用している。

Toggl： Time Tracking Software, Project Planning & Hiring Tools
https://toggl.com/

Toogl Track はログを書き出す Export 機能がある。僕はそれを FileMaker に取り込んで管理したい。しかし毎回ウェブでダウンロードするのは手間なので、API を使うことで自動的にダウンロードできるようにしたい。FileMaker Server を利用すれば例えば毎日、前日のログをダウンロードして情報を蓄積できるようになる。

環境：macOS Catalina Version 10.15.6（英語環境）、FileMaker Pro 18

（１）「My Profile」で API Token を確認する。

My Profile - Toggl Track
https://track.toggl.com/profile/

（２）workspace_id を確認する。「Reports」ページ等の URL に表示される７桁の数字だ。

Reports
https://track.toggl.com/reports/summary/{workspace_id}

（３）まずは Mac の curl コマンドで、Toggl API を使ってレポートを取得してみよう。

Mac のターミナルで以下のコマンドを実行し、レポートを取得する。

$ curl -u {API Token}:api_token -X GET "https://api.track.toggl.com/reports/api/v2/summary?workspace_id={workspace_id}&user_agent={メールアドレスもしくはアプリケーション名}&since={開始日}&until={終了日}"

user_agent 部分は適当な文字列（api_test など）でいい。

開始日と終了日は YYYY-MM-DD のフォーマットで記入する。開始日と終了日を指定しなければ、４～６日前あたりの記録が取得される。

時刻（開始日時）は日本時間で表示される。

所要時間はミリ秒で取得される。見やすくするために変換が必要だ（後述）。

（４）３の結果では JSON が見にくいので jq コマンドをインストールする。

$ brew install jq

改めて３のコマンドを jq コマンドに渡してみる。

$ curl -u {API Token}:api_token -X GET "https://api.track.toggl.com/reports/api/v2/summary?workspace_id={workspace_id}&user_agent={メールアドレスもしくはアプリケーション名}&since={開始日}&until={終了日}" | jq

これで見やすくなったはずだ。

（５）FileMaker に取り込むには、Insert from URL スクリプトステップを使う。

僕が今回欲しいデータは日付、プロジェクト名、所要時間だ。

時刻（開始日時）は 2023-02-21T11:24:21 のようなフォーマットで取得されるので、2023-02-21 の部分だけ抜き出したい。所要時間はミリ秒表示なので、一旦 H:MM:SS という表示に変換し、さらに H 時間 MM 分に変換しよう。

そういうわけで、FileMaker で以下のフィールドを作成しておく。

・local_start
・project
・time
・_HMMSS
・_Date
・_時間分

_ で始まるフィールドは、Toggl API の素のデータではなく、FileMaker で計算し直したフィールドであることを指すものとする。

その上で以下のようなスクリプトを作成する。

# Toggle API 用の変数設定。
Set Variable [ $workspace_id ; Value: "{workspace_id}" ] 
Set Variable [ $api ; Value: "{API Token}" ] 
Set Variable [ $since ; Value: GetAsText ( Year ( Get ( CurrentDate ) - 1) ) & "-" & GetAsText ( Month ( Get ( CurrentDate ) - 1) ) & "-" & GetAsText ( Day ( Get ( CurrentDate ) - 1) ) ] 
Set Variable [ $until ; Value: GetAsText ( Year ( Get ( CurrentDate ) - 1) ) & "-" & GetAsText ( Month ( Get ( CurrentDate ) - 1) ) & "-" & GetAsText ( Day ( Get ( CurrentDate ) - 1) ) ] 
# 
# Toogl API から取得。
Insert from URL [ Select ; With dialog: Off ; Target: $result ; "https://api.track.toggl.com/reports/api/v2/summary?workspace_id=" & $workspace_id & "&user_agent=api_test&since=" & $since & "&until=" & $until & "\"" ; cURL options: "-u " & $api & ":api_token" ] 
# 
# JSON の値が存在する場合のみスクリプトを実行するため、JSON の値の数を数える。そのための変数 ItemCount を設定。
Set Variable [ $ItemCount ; Value: ValueCount ( JSONListKeys ( $result ; "" ) ) ] 
# 
Set Variable [ $i ; Value: 0 ] 
# 
If [ $ItemCount > 0 ] 
	# 
	Loop
		New Record/Request
		Set Field [ Table::project ; JSONGetElement ( $result ; "data[" & $i & "].title.project" ) ] 
		Set Field [ Table::time ; JSONGetElement ( $result ; "data[" & $i & "].time" ) ] 
		Set Field [ Table::local_start ; JSONGetElement ( $result ; "data[" & $i & "].items[0].local_start" ) ] 
		Set Field [ Table::_HMMSS ; GetAsTime ( Div ( Table::time ; 1000 ) ) & SerialIncrement ( ".00" ; Mod ( Table::time /10 ; 100 ) ) ] 
		Set Field [ Table::_Date ; Left ( Table::local_start ; 10 ) ] 
		Set Field [ Table::_時間分 ; Left ( Table::_HMMSS ; 1 ) & "時間" & Middle ( Table::_HMMSS ; 3 ; 2 ) & "分" ] 
		# 
		Set Variable [ $i ; Value: $i + 1 ] 
		# 
		# プロジェクト名が取得できなくなったらループを抜ける。
		Exit Loop If [ JSONGetElement ( $result ; "data[" & $i & "].title.project" ) = "" ] 
	End Loop
	# 
End If