M2 Suppy Net Change

「M2マネーサプライのネット変化（Net Change）」を表示するためのものです。各国のM2マネーサプライデータを取得し、それらを合計した「ネット変化」を計算します。そして、そのネット変化を前日と比較して、その差分を表示します。

サンプル

免責事項

このインジケーターは、すべてご自身の責任でご利用ください。本インジケーターの使用によるいかなる損失や損害について、当方は一切の責任を負いかねます。
また、本インジケーターの動作の正常性や正確性については一切保証いたしません。予期せぬ動作やエラーが発生する可能性があるため、ご理解の上でご利用いただきますようお願いいたします。

設定方法はこちら

インジケータの目的

このインジケーターにおける「増減」は、世界の主要国のM2マネーサプライの総額が前日と比べてどのように変化したかを示しています。この増減は、経済全体における資金の流入や流出の動向を反映しており、いくつかの重要な意味を持ちます。

増加（プラスの値）の意味

インジケーターの出力がプラスの場合、これは前日と比べて対象となる国々のM2マネーサプライが増加したことを示します。この増加は、以下のようなことを意味する可能性があります。

1. 経済活動の活発化: 資金が市場に投入され、消費や投資が増加している可能性があります。これは、経済の活性化を意味し、景気が拡大している兆候かもしれません。

2. インフレーション圧力の上昇: M2の増加は、過剰な資金供給が物価を押し上げ、インフレーションを引き起こすリスクを伴うことがあります。特に中央銀行が意図的に貨幣供給を増やしている場合、これはインフレ目標を達成するための政策の一環である可能性があります。

3. 中央銀行の金融緩和政策: 中央銀行が量的緩和や金利引き下げを通じてマネーサプライを増やしている場合があります。これは、景気を刺激するための措置であることが多いです。

減少（マイナスの値）の意味

インジケーターの出力がマイナスの場合、これは前日と比べて対象となる国々のM2マネーサプライが減少したことを示します。この減少は、以下のようなことを意味する可能性があります。

1. 経済活動の低下: 資金が市場から流出している、あるいは消費や投資が減少している可能性があります。これは、景気が縮小している兆候かもしれません。

2. デフレーションのリスク: マネーサプライの減少は、物価が下落するデフレーション圧力を示すことがあります。これは、経済の停滞や不況を引き起こす可能性があります。

3. 金融引き締め政策: 中央銀行が金融政策を引き締め、金利を引き上げるなどしてマネーサプライを減らしている場合があります。これは、インフレを抑制するための措置であることが多いです。

まとめ

このインジケーターの増減は、世界の主要国におけるマネーサプライの変動を示し、その変動が経済に与える影響を理解するための指標となります。プラスの値は資金の増加を、マイナスの値は資金の減少を意味し、それぞれが経済活動や市場の状況に対する重要な示唆を提供します。

インジケータの仕様

グローバル流動性の日々の増減をヒストグラム(バー)とラインで表示します。

採用している国

アメリカ合衆国 (USA): USM2（アメリカのM2マネーサプライ）
ヨーロッパ (EU): EUM2（ユーロ圏のM2マネーサプライ）
中国 (China): CNM2（中国のM2マネーサプライ）
日本 (Japan): JPM2（日本のM2マネーサプライ）
イギリス (United Kingdom): GBM2（イギリスのM2マネーサプライ）
カナダ (Canada): CAM2（カナダのM2マネーサプライ）
オーストラリア (Australia): AUM3（オーストラリアのM3マネーサプライ）
インド (India): INM2（インドのM2マネーサプライ）
スイス (Switzerland): CHM2（スイスのM2マネーサプライ）
ロシア (Russia): RUM2（ロシアのM2マネーサプライ）
ブラジル (Brazil): BRM2（ブラジルのM2マネーサプライ）
韓国 (South Korea): KRM2（韓国のM2マネーサプライ）
メキシコ (Mexico): MXM2（メキシコのM2マネーサプライ）
インドネシア (Indonesia): IDM2（インドネシアのM2マネーサプライ）
南アフリカ (South Africa): ZAM2（南アフリカのM2マネーサプライ）
マレーシア (Malaysia): MYM2（マレーシアのM2マネーサプライ）
スウェーデン (Sweden): SEM2（スウェーデンのM2マネーサプライ）

このインジケーターは、これら17の国や地域のM2マネーサプライデータを基に、全体の変化を分析し、視覚的に表示します。

移動平均

ヒストグラムとラインそれぞれでSMA、EMAの選択、および移動平均の期間が選べます。

ヒストグラムとラインと書きましたが、実際は選べるので、ライン2本なども可能ですが、ヒストグラムは移動平均期間を1として純粋な増減とし、ラインは移動平均を選ぶというような使い方がお勧めです。

コード

2024/8/26 目盛表示の単位の修正など

//@version=5
indicator('M2 Supply Net Change', overlay=false, scale=scale.right, format=format.volume)

// 各データの入力オプション
usa_active = input(true, title = "USM2 (USA Money Supply)")
europe_active = input(true, title = "EUM2 (Europe Money Supply)")
china_active = input(true, title = "CNM2 (China Money Supply)")
japan_active = input(true, title = "JPM2 (Japan Money Supply)")
other_m2_active = input(true, title = "Other Countries M2")

// カラーの入力オプション
positive_color = input.color(color.blue, title = "Positive Color")
negative_color = input.color(color.orange, title = "Negative Color")
line_color = input.color(color.white, title = "Line Color")

// スムージング方法の選択オプション
hist_smoothing_method = input.string(title="Histogram Smoothing Method", defval="SMA", options=["EMA", "SMA"])
line_smoothing_method = input.string(title="Line Smoothing Method", defval="SMA", options=["EMA", "SMA"])

// 棒グラフとラインの移動平均のスムージング期間を別々に設定
hist_smoothing_period = input(5, title = "Histogram Smoothing Period") // 棒グラフのスムージング期間
line_smoothing_period = input(5, title = "Line Smoothing Period") // ラインのスムージング期間

// 各データの取得
usa = usa_active ? request.security("ECONOMICS:USM2", "D", close, currency=currency.USD) : 0
eu = europe_active ? request.security("ECONOMICS:EUM2 * EURUSD", "D", close, currency=currency.USD) : 0
china = china_active ? request.security("ECONOMICS:CNM2 * CNYUSD", "D", close, currency=currency.USD) : 0
japan = japan_active ? request.security("ECONOMICS:JPM2 * JPYUSD", "D", close, currency=currency.USD) : 0
uk = other_m2_active ? request.security("ECONOMICS:GBM2 * GBPUSD", "D", close, currency=currency.USD) : 0
canada = other_m2_active ? request.security("ECONOMICS:CAM2 * CADUSD", "D", close, currency=currency.USD) : 0
australia = other_m2_active ? request.security("ECONOMICS:AUM3 * AUDUSD", "D", close, currency=currency.USD) : 0
india = other_m2_active ? request.security("ECONOMICS:INM2 * INRUSD", "D", close, currency=currency.USD) : 0
switzerland = other_m2_active ? request.security("ECONOMICS:CHM2 * CHFUSD", "D", close, currency=currency.USD) : 0
russia = other_m2_active ? request.security("ECONOMICS:RUM2 * RUBUSD", "D", close, currency=currency.USD) : 0
brazil = other_m2_active ? request.security("ECONOMICS:BRM2 * BRLUSD", "D", close, currency=currency.USD) : 0
korea = other_m2_active ? request.security("ECONOMICS:KRM2 * KRWUSD", "D", close, currency=currency.USD) : 0
mexico = other_m2_active ? request.security("ECONOMICS:MXM2 * MXNUSD", "D", close, currency=currency.USD) : 0
indonesia = other_m2_active ? request.security("ECONOMICS:IDM2 * IDRUSD", "D", close, currency=currency.USD) : 0
africa = other_m2_active ? request.security("ECONOMICS:ZAM2 * ZARUSD", "D", close, currency=currency.USD) : 0
malaysia = other_m2_active ? request.security("ECONOMICS:MYM2 * MYRUSD", "D", close, currency=currency.USD) : 0
sweden = other_m2_active ? request.security("ECONOMICS:SEM2 * SEKUSD", "D", close, currency=currency.USD) : 0

// 流入流出の計算
inflow = usa + eu + china + japan + uk + canada + australia + india + switzerland + russia + brazil + korea + mexico + indonesia + africa + malaysia + sweden

// ネット変化の計算
net_change = inflow

// 前日との変化を計算
net_change_diff = net_change - net_change[1]

// スムージング関数の選択
smooth_func(series, period, method) =>
    method == "EMA" ? ta.ema(series, period) : ta.sma(series, period)

// オシレータの計算
smoothed_net_change_hist = smooth_func(net_change_diff, hist_smoothing_period, hist_smoothing_method)
smoothed_net_change_line = smooth_func(net_change_diff, line_smoothing_period, line_smoothing_method)

// フォーマットされた値をプロットする
plot(smoothed_net_change_hist, title="Net Change (Histogram)", color=color.new(smoothed_net_change_hist >= 0 ? positive_color : negative_color, 0), style=plot.style_histogram, linewidth=2)
plot(smoothed_net_change_line, title="Net Change (Line)", color=line_color, linewidth=2)